RFID and ESP32 video kit with RC522 reader, tags and OLED display

Comment ajouter un lecteur RFID à votre ESP32 (Câblage et code pour RC522)

Le RFID semble complexe, mais avec un ESP32, c’est l’un des moyens les plus rapides de donner à un projet un côté ingénieux. Vous approchez une carte, et il se passe quelque chose. C’est tout le principe, et les possibilités sont nombreuses : un effet de costume activé par contact, un déclencheur caché cousu dans une veste, un petit système d’accès pour votre atelier, une œuvre d’art interactive. Dans ce tutoriel, nous branchons un lecteur RC522, lisons l’identifiant de vos badges, puis configurons la carte pour qu’elle ne réagisse qu’au badge de votre choix. Cela prend environ une heure, aucune soudure n’est nécessaire, et vous pouvez suivre l’intégralité du montage dans ma vidéo.

Le RFID en un paragraphe

Le lecteur crée un petit champ électromagnétique. Lorsqu’un badge entre dans son champ d’action, la petite puce qu’il contient s’alimente grâce à ce champ et renvoie son identifiant unique, qui n’est qu’une courte série de chiffres. Le badge n’a pas besoin de pile. Votre ESP32 lit ce numéro et le compare à ceux que vous lui avez indiqués. S’il correspond, il déclenche une action ; sinon, il en déclenche une autre. Pour que cela fonctionne, les badges doivent être proches du lecteur, alors considérez plutôt comme un contact qu’une simple approche.

Ce dont vous avez besoin

  • Une carte de développement ESP32 à 30 broches, comme l’ESP32 Development Board 30-Pin (USB-C)
  • Un lecteur RFID RC522 (13,56 MHz, SPI) avec une carte et un ou deux porte-clés RFID
  • Une plaque d’essai sans soudure et des fils de liaison
  • Facultatif : un écran OLED I2C de 0,96 pouce pour afficher des informations
  • Un câble de données USB-C (pas un câble de charge uniquement)
  • PlatformIO dans VS Code ou l’IDE Arduino

Si vous souhaitez tout recevoir dans un seul kit, le RFID + ESP32 Video Kit contient toutes les pièces nécessaires et permet de réaliser un montage de niveau 1 sans soudure.

Étape 1 : alimentation et masse

Insérez l’ESP32 dans un côté de la plaque d’essai afin que les broches dont vous avez besoin restent accessibles, puis placez le RC522 à côté. Reliez la broche 3,3 V de l’ESP32 au rail d’alimentation, puis reliez ce rail à la broche 3,3 V du RC522. Faites de même pour la masse. C’est important : le RC522 fonctionne en 3,3 V, ne le connectez donc pas au 5 V.

Étape 2 : les connexions SPI

Voici les connexions que j’ai utilisées dans la vidéo, qui sont standard pour la plupart des cartes ESP32 :

  • RC522 SDA (également indiqué SS) sur GPIO 5
  • RC522 SCK sur GPIO 18
  • RC522 MOSI sur GPIO 23
  • RC522 MISO sur GPIO 19
  • RC522 RST sur GPIO 2
  • La broche IRQ n’est pas utilisée

Comme toujours, vérifiez le brochage de votre carte avant de la brancher. Si vous souhaitez revoir comment lire le brochage de l’ESP32, le guide du blog explique la marche à suivre.

Étape 3 (facultative) : ajouter l’OLED

L’écran ne sert qu’à afficher des informations, mais je le trouve tellement utile que je ne l’omette que rarement. Il utilise l’I2C, il nécessite donc une alimentation, une masse, SDA sur GPIO 21 et SCL sur GPIO 22.

Étape 4 : configurer PlatformIO et lire les identifiants de vos badges

Créez un nouveau projet et ajoutez la bibliothèque du lecteur dans platformio.ini :

[env:esp32dev]
platform = espressif32
board = esp32dev
framework = arduino
monitor_speed = 115200
lib_deps = miguelbalboa/MFRC522

Ensuite, utilisez un court programme qui affiche l’identifiant de tout badge présenté au lecteur :

#include <Arduino.h>
#include <SPI.h>
#include <MFRC522.h>

const uint8_t SS_PIN = 5;
const uint8_t RST_PIN = 2;
MFRC522 rfid(SS_PIN, RST_PIN);

void setup() {
  Serial.begin(115200);
  SPI.begin();
  rfid.PCD_Init();
  Serial.println("Scannez un badge");
}

void loop() {
  if (!rfid.PICC_IsNewCardPresent() || !rfid.PICC_ReadCardSerial()) return;

  Serial.print("UID:");
  for (byte i = 0; i < rfid.uid.size; i++) {
    Serial.print(rfid.uid.uidByte[i] < 0x10 ? " 0" : " ");
    Serial.print(rfid.uid.uidByte[i], HEX);
  }
  Serial.println();
  rfid.PICC_HaltA();
}

Téléversez-le, ouvrez le moniteur série et scannez chacun de vos badges, autocollants et porte-clés RFID à tour de rôle. Notez l’identifiant de chacun. Vous aurez besoin de ces numéros à l’étape suivante.

Étape 5 : faire réagir la carte au bon badge

Le principe est simple. Enregistrez l’identifiant du badge que vous souhaitez reconnaître, puis comparez chaque lecture à celui-ci. Dans la vidéo, j’utilise cette méthode pour afficher un cœur sur l’OLED lorsque le bon badge est détecté et un petit squelette dansant pour tous les autres. La version intégrale de ce code se trouve sur mon GitHub, dont le lien figure dans la description de la vidéo. Voici le cœur de la logique :

// Remplacez par les octets que vous avez notés à l’étape 4
byte myTag[4] = {0xDE, 0xAD, 0xBE, 0xEF};

bool matches() {
  if (rfid.uid.size != 4) return false;
  for (byte i = 0; i < 4; i++) {
    if (rfid.uid.uidByte[i] != myTag[i]) return false;
  }
  return true;
}

Appelez matches() après une lecture réussie. Si elle renvoie true, déclenchez l’action souhaitée ; sinon, exécutez l’action par défaut. Les octets fictifs ci-dessus ne sont qu’un exemple, utilisez donc les vôtres.

Dépannage

  • Rien ne s’affiche : vérifiez d’abord le câble de données, puis la connexion du lecteur au 3,3 V.
  • Les lectures sont instables : maintenez le badge à plat et près du lecteur, et éloignez tout objet métallique de celui-ci.
  • Les identifiants sont illisibles ou affichent zéro : vérifiez à nouveau MISO, MOSI et SCK, car ce sont les fils les plus faciles à inverser par erreur.
  • Votre carte possède des broches différentes : utilisez ses broches SPI et mettez à jour SS_PIN et RST_PIN en conséquence.

Où aller ensuite

Une fois la détection du badge fonctionnelle, la réponse peut être n’importe quoi. Allumez une LED NeoPixel, jouez un son, déverrouillez un servomoteur ou envoyez un message via Wi-Fi. Pour les objets connectés à porter, le RC522 est assez volumineux, mais les mêmes badges fonctionnent avec des lecteurs plus petits, vous pouvez donc réaliser un prototype sur plaque d’essai et réduire la taille du matériel par la suite. Un badge cousu dans une manche ou une sangle de sac peut devenir un déclencheur caché que vous seul connaissez.

Regardez l’intégralité du montage ici : La façon la plus simple d’ajouter le RFID à un ESP32 (montage de 15 minutes). J’adorais savoir ce que vous prévoyez de déclencher avec, alors dites-le-moi dans les commentaires.

Christine

Retour au blog

Laisser un commentaire